Come creare il modello
|
|
Il file StarSimu è stato realizzato impostando il
foglio di lavoro di Excel nella maniera illustrata qui sotto. Seguendo
le medesime istruzioni, è possibile creare un modello analogo al
nostro anche utilizzando fogli elettronici diversi da Excel.
Ecco le istruzioni per creare il modello:
1) Setting globale
- Assegnare a tutte le celle del foglio il formato scientifico (o esponenziale),
con una cifra decimale (in questo formato, un numero come "130"
appare scritto come "1,3E +02", che sta per "1,3*10^2",
dove "10^2" e, più in generale, "10^n", equivale
a scrivere un "1" seguito da n zeri).
- Allineare al centro tutte le celle.
2) Etichette
- Inserire, in celle poste alle corrispondenti coordinate, le varie etichette
visualizzate in grassetto nella schermata della nana bianca.
- Assegnare alle celle C3, C5, F1, F5 il formato decimale, rispettivamente
con 4, 2, 1, 0 cifre decimali.
3) Valori
- Assegnare i valori in input: suggeriamo di porre "1,0E +11"
nella cella C1, "0,8" nella cella F1, "1,333.." nella
cella C3, e "4,94E +14" nella cella F3 (il significato fisico
della presente scelta dei parametri verrà discusso più avanti).
- Inserire "0,0E +00" nelle celle A8, D8, I8, e J8.
4) Formule
| Cella |
Formula |
B8
C8
A9
E8 |
=C1
=F3*B8^C3
=A8 + $F$1*100000
=A8/($F$5*100000) |
- Copiare le celle A9 e E8 rispettivamente nelle zone A10..A1000 e E9..E1000
D9
H8 |
=D8 + 4,189*B8*(A9^3-A8^3)
=D8/($C$5*2E+33) |
- Copiare le celle D9 e H8 rispettivamente nelle zone D10..D1000 e H9..H1000
C9
G8 |
=C8 - 6.673E-8*B8*(A9-A8)*D9/A9^2
=C8/$C$8 |
- Copiare le celle C9 e G8 rispettivamente nelle zone C10..C1000 e G9..G1000
B9
F8 |
=(C9/$F$3)^(1/$C$3)
=B8/$B$8 |
- Copiare le celle B9 e F8 rispettivamente nelle zone B10..B1000 e F9..F1000
I9
J9 |
=SE(I8=0;SE(C9>0;0;(D9+D8)/2);1E-90)
=SE(J8=0;SE(C9>0;0;(A9+A8)/2);1E-90) |
- Copiare le celle I9 e J9 rispettivamente nelle zone I10..I1000 e J10..J1000
C5
F5 |
=MAX(I8:I1000)/2E+33
=MAX(J8:J1000)/100000 |
5) Grafico
- Selezionare un grafico del tipo X-Y.
- Impostare come ascissa le celle della colonna E, a partire dalla E8
fino ad arrivare a quella che rappresenta il confine della stella (quest’ultimo,
nella presente scelta dei parametri, corrisponde alla cella E895).
- Impostare, quali tre diverse ordinate, le celle delle colonne F, G,
e H, rispettivamente, anche qui partendo da quelle poste alla riga 8 fino
ad arrivare a quelle corrispondenti al confine della stella.
Ritorna alla home page di StarSimu
A.
Marchini & M. Menichella - Ultimo aggiornamento 1/12/1997